[VB.NET] 型パラメーター(Of T)を使って動的に型を指定してDictionaryからクラスに変換する

Module main
    ''' <summary>
    ''' メイン
    ''' </summary>
    Sub main()
        '変換テスト用のディクショナリを作成
        Dim src As New Dictionary(Of String, Object)
        src.Add("item1", "テスト")
        src.Add("item2", 123)
        src.Add("item3", New Dictionary(Of String, Object) From {{"param1", "パラメータ"}, {"param2", 456}})


        '型パラメーター(Of T)を使って動的に型を指定してDictionaryからクラスに変換する
        Dim rec As record
        rec = DictionaryToModel(Of record)(src)

        Console.WriteLine(rec.item1)
        Console.WriteLine(rec.item2)
        Console.WriteLine(rec.item3.param1)
        Console.WriteLine(rec.item3.param2)
    End Sub
    ''' <summary>
    ''' 型パラメーター(Of T)を使って動的に型を指定してDictionaryからクラスに変換する
    ''' </summary>
    ''' <typeparam name="T">型パラメーター</typeparam>
    ''' <param name="src">ディクショナリー</param>
    ''' <returns>変換後のレコード</returns>
    Friend Function DictionaryToModel(Of T)(ByVal src As Dictionary(Of String, Object)) As T
        Return CType(DictionaryToModel(GetType(T), src), T)
    End Function
    ''' <summary>
    ''' Type型を使って動的に型を指定してDictionaryからクラスに変換する
    ''' </summary>
    ''' <param name="typ">Type型</param>
    ''' <param name="src">ディクショナリー</param>
    ''' <returns>変換後のレコード</returns>
    Friend Function DictionaryToModel(ByVal typ As Type, ByVal src As Dictionary(Of String, Object)) As Object
        Dim result As Object = Activator.CreateInstance(typ)
        Dim pi As Reflection.PropertyInfo
        Dim val As Object

        For Each item As KeyValuePair(Of String, Object) In src
            pi = typ.GetProperty(item.Key)

            If TypeOf item.Value Is Dictionary(Of String, Object) Then
                'itemがDictionaryなら再帰呼び出し
                val = DictionaryToModel(pi.PropertyType, CType(item.Value, Dictionary(Of String, Object)))
            Else
                val = item.Value
            End If

            pi.SetValue(result, val)
        Next
        Return result
    End Function
End Module

''' <summary>
''' レコードクラス
''' </summary>
Public Class record
    Public Property item1 As String
    Public Property item2 As Integer

    ''' <summary>
    ''' レコードパラメータークラス
    ''' </summary>
    ''' <returns></returns>
    Public Property item3 As record_param
End Class

''' <summary>
''' レコードパラメータークラス
''' </summary>
Public Class record_param
    Public Property param1 As String
    Public Property param2 As Integer

End Class