[VB.NET] REST API⑭ OAuth2.0 認証＃1（APIに認証機能を実装）

Imports System
Imports System.Collections.Generic
Imports System.Linq
Imports System.Web.Http

Public Module WebApiConfig
    Public Sub Register(ByVal config As HttpConfiguration)
        ' Web API の設定およびサービス

        'Bearer token 認証
        config.SuppressDefaultHostAuthentication()
        config.Filters.Add(New HostAuthenticationFilter(Microsoft.Owin.Security.OAuth.OAuthDefaults.AuthenticationType))


        ' Web API ルート
        config.MapHttpAttributeRoutes()

        config.Routes.MapHttpRoute(
            name:="DefaultApi",
            routeTemplate:="api/{controller}/{id}",
            defaults:=New With {.id = RouteParameter.Optional}
        )
    End Sub
End Module

Imports System.Security.Claims
Imports System.Threading.Tasks
Imports Microsoft.Owin.Security.OAuth


Public Class OAuthProvider
    Inherits OAuthAuthorizationServerProvider

    ''' <summary>
    ''' クライアント有効チェック
    ''' </summary>
    ''' <param name="context"></param>
    ''' <returns></returns>
    Public Overrides Function ValidateClientAuthentication(ByVal context As OAuthValidateClientAuthenticationContext) As Task
        context.Validated()
        Return Task.FromResult(0)
    End Function

    ''' <summary>
    ''' ユーザー認証
    ''' </summary>
    ''' <param name="context"></param>
    ''' <returns></returns>
    Public Overrides Function GrantResourceOwnerCredentials(ByVal context As OAuthGrantResourceOwnerCredentialsContext) As Task

        'テスト用なのでユーザー／パスワードは固定
        Dim user As String = "user1"
        Dim pass As String = "password1"

        'ユーザー／パスワードをチェック
        If context.UserName = user AndAlso context.Password = pass Then

            'identityを生成
            Dim identity = New ClaimsIdentity(context.Options.AuthenticationType)
            identity.AddClaims({New Claim(ClaimTypes.GivenName, context.UserName), New Claim(ClaimTypes.Role, "Admin")})
            context.Validated(identity)
        Else
            '拒否する
            context.Rejected()
        End If

        Return Task.FromResult(0)
    End Function
End Class

Imports Microsoft.Owin
Imports Microsoft.Owin.Security.OAuth
Imports Owin

<Assembly: OwinStartup(GetType(Startup))>

Public Class Startup
    Public Sub Configuration(ByVal app As IAppBuilder)
        app.UseOAuthBearerTokens(New OAuthAuthorizationServerOptions With {
            .TokenEndpointPath = New PathString("/Token"),
            .Provider = New OAuthProvider,
            .AccessTokenExpireTimeSpan = TimeSpan.FromMinutes(1),
            .AllowInsecureHttp = True
        })
    End Sub
End Class