[VB.NET] REST API⑬ ビューからWeb APIにファイルをアップロード

Imports System.Net
Imports System.Web.Http

Namespace Controllers
    Public Class ApiTestController
        Inherits ApiController

        ' POST: api/ApiTest/PostFileStream
        <HttpPost>
        <ActionName("PostFileStream")>
        Public Function PostFileStream(ByVal value As System.Net.Http.HttpRequestMessage) As System.Net.Http.HttpResponseMessage

            '保存先のファイルパス（App_Data）
            Dim path As String
            path = HttpContext.Current.Server.MapPath("~/App_Data/" & value.Content.Headers.ContentDisposition.FileName)


            Using mem As New System.IO.MemoryStream()
                '読み出し
                mem.Position = 0
                value.Content.ReadAsStreamAsync.Result.CopyTo(mem)

                'ファイルを保存
                Using sr As New System.IO.FileStream(path, System.IO.FileMode.OpenOrCreate, System.IO.FileAccess.Write)
                    mem.Position = 0
                    mem.CopyTo(sr)
                End Using
            End Using

            'レスポンスメッセージ作成
            Dim ret As System.Net.Http.HttpResponseMessage
            ret = New System.Net.Http.HttpResponseMessage(HttpStatusCode.OK)

            '成功メッセージを設定
            Dim content As New Net.Http.StringContent("The file was saved successfully !", Encoding.UTF8, "text/plain")
            ret.Content = content

            Return ret
        End Function
    End Class
End Namespace

Imports System
Imports System.Collections.Generic
Imports System.Linq
Imports System.Web.Http

Public Module WebApiConfig
    Public Sub Register(ByVal config As HttpConfiguration)
        ' Web API の設定およびサービス


        'jsonをブラウザで表示させる
        config.Formatters.JsonFormatter.SupportedMediaTypes.Add(New System.Net.Http.Headers.MediaTypeHeaderValue("text/html"))


        ' Web API ルート
        config.MapHttpAttributeRoutes()

        'ファイルアップロード用のAPI
        config.Routes.MapHttpRoute(
            name:="CustomApi",
            routeTemplate:="api/{controller}/{action}",
            defaults:=New With {.id = RouteParameter.Optional}
        )

        config.Routes.MapHttpRoute(
            name:="DefaultApi",
            routeTemplate:="api/{controller}/{id}",
            defaults:=New With {.id = RouteParameter.Optional}
        )
    End Sub
End Module

Imports System.Web.Mvc
Namespace Controllers
    Public Class ViewTestController
        Inherits Controller

        Function upload() As ActionResult
            ViewData("msg") = ""
            Return View()
        End Function

        <HttpPost()>
        <ValidateAntiForgeryToken>
        Function upload(ByVal post_file As HttpPostedFileBase) As ActionResult
            If (IsNothing(post_file)) Then
                ViewData("msg") = "ファイルを指定してください！"
            Else
                'レコード作成するAPIのURL
                Dim url As String
                url = DirectCast(Request, System.Web.HttpRequestWrapper).Url.GetLeftPart(UriPartial.Authority) & "/api/ApiTest/PostFileStream"

                'POST
                Dim result As System.Net.Http.HttpResponseMessage
                Dim clt As New Net.Http.HttpClient
                Dim content As Net.Http.StreamContent

                'ストリームコンテンツ
                content = New Net.Http.StreamContent(post_file.InputStream)

                'コンテンツタイプ
                content.Headers.ContentDisposition = New System.Net.Http.Headers.ContentDispositionHeaderValue("attachment")
                content.Headers.ContentType = New System.Net.Http.Headers.MediaTypeHeaderValue(post_file.ContentType)

                'ファイル名
                content.Headers.ContentDisposition.FileName = post_file.FileName

                'アップロード実行
                result = clt.PostAsync(url, content).Result

                Dim model As New ViewTestParam With {.Item1 = ""}
                'メッセージを取り出し
                ViewData("msg") = String.Format("{0} ({1})", result.Content.ReadAsStringAsync.Result, post_file.FileName)

            End If
            Return View()
        End Function
    End Class
End Namespace

@Code
    ViewData("Title") = "upload"
End Code

<h2>upload</h2>

@Html.Label("message_label", ViewData("msg").ToString, New With {.style = "color:red;"})

<div>
    @Using (Html.BeginForm("upload", "ViewTest", FormMethod.Post, New With {.enctype = "multipart/form-data"}))
        @Html.AntiForgeryToken()
        @<input type="file" name="post_file" />
        @<input type="submit" value="アップロード" />

    End Using
</div>